Classic theorems without their usual tools

import Mathlib.Data.Nat.Choose.Sum
import Mathlib.Data.Nat.Choose.Dvd

theorem Lemma.fermat_little_key (p a : ℕ) (hp : p.Prime) :
    ∃ t, (a + 1) ^ p = a ^ p + 1 + p * t := by
  obtain ⟨m, rfl⟩ : ∃ m, p = m + 1 := ⟨p - 1, by have := hp.two_le; omega⟩
  rw [add_pow, Finset.sum_range_succ, Finset.sum_range_succ']
  simp only [Nat.cast_id]
  have hd : (m + 1) ∣ ∑ k ∈ Finset.range m,
      a ^ (k + 1) * 1 ^ (m + 1 - (k + 1)) * (m + 1).choose (k + 1) := by
    apply Finset.dvd_sum
    intro k hk
    rw [Finset.mem_range] at hk
    exact Dvd.dvd.mul_left (hp.dvd_choose_self (by omega) (by omega)) _
  obtain ⟨t, ht⟩ := hd
  refine ⟨t, ?_⟩
  rw [ht]
  simp only [pow_zero, one_pow, mul_one, one_mul, Nat.choose_zero_right, Nat.choose_self,
    Nat.sub_self]
  generalize a ^ (m + 1) = x
  generalize (m + 1) * t = y
  omega

theorem Lemma.fermat_little :
    ∀ p a : ℕ, p.Prime → a ^ p % p = a % p := by
  intro p a hp
  induction a with
  | zero =>
    rw [zero_pow hp.ne_zero]
  | succ n ih =>
    obtain ⟨t, ht⟩ := Lemma.fermat_little_key p n hp
    rw [ht, Nat.add_mul_mod_self_left, Nat.add_mod, ih, ← Nat.add_mod]

import Mathlib.FieldTheory.Finite.Basic

theorem Lemma.two_squares :
    ∀ p : ℕ, p.Prime → p % 4 = 1 → ∃ a b : ℕ, a ^ 2 + b ^ 2 = p := by
  intro p hp h4
  haveI := Fact.mk hp
  obtain ⟨x, hx⟩ : IsSquare (-1 : ZMod p) := by
    have hne : (-1 : ZMod p) ≠ 0 := neg_ne_zero.mpr one_ne_zero
    have hc : ringChar (ZMod p) ≠ 2 := by
      rw [ZMod.ringChar_zmod_n]; omega
    rw [FiniteField.isSquare_iff hc hne, ZMod.card]
    obtain ⟨t, ht⟩ : ∃ t, p / 2 = 2 * t := ⟨p / 4, by omega⟩
    rw [ht, pow_mul]; simp
  obtain ⟨m, hm⟩ : ∃ m, m = Nat.sqrt p := ⟨_, rfl⟩
  have hm1 : m * m ≤ p := hm ▸ Nat.sqrt_le p
  have hm2 : p < (m + 1) * (m + 1) := hm ▸ Nat.lt_succ_sqrt p
  have hmp : m * m ≠ p := by
    intro h
    rcases hp.eq_one_or_self_of_dvd m (Dvd.intro m h) with h1 | h1
    · subst h1; exact hp.one_lt.ne (by omega)
    · subst h1
      have := Nat.eq_of_mul_eq_mul_left hp.pos (h.trans (mul_one m).symm)
      exact hp.one_lt.ne this.symm
  have hcard : Fintype.card (ZMod p) < Fintype.card (Fin (m + 1) × Fin (m + 1)) := by
    simp only [ZMod.card, Fintype.card_prod, Fintype.card_fin]; exact hm2
  obtain ⟨⟨u1, v1⟩, ⟨u2, v2⟩, hne, heq⟩ := Fintype.exists_ne_map_eq_of_card_lt
    (fun uv : Fin (m + 1) × Fin (m + 1) =>
      ((uv.1 : ℕ) : ZMod p) + x * ((uv.2 : ℕ) : ZMod p)) hcard
  simp only at heq
  have hu1 := u1.isLt
  have hu2 := u2.isLt
  have hv1 := v1.isLt
  have hv2 := v2.isLt
  obtain ⟨a, ha⟩ : ∃ a : ℤ, a = ((u1 : ℕ) : ℤ) - ((u2 : ℕ) : ℤ) := ⟨_, rfl⟩
  obtain ⟨b, hb⟩ : ∃ b : ℤ, b = ((v1 : ℕ) : ℤ) - ((v2 : ℕ) : ℤ) := ⟨_, rfl⟩
  have hdiv : (p : ℤ) ∣ a ^ 2 + b ^ 2 := by
    rw [← ZMod.intCast_zmod_eq_zero_iff_dvd, ha, hb]
    push_cast
    have h' : ((u1 : ℕ) : ZMod p) - ((u2 : ℕ) : ZMod p)
        = -(x * (((v1 : ℕ) : ZMod p) - ((v2 : ℕ) : ZMod p))) := by
      linear_combination heq
    rw [h']
    linear_combination (-((((v1 : ℕ) : ZMod p) - ((v2 : ℕ) : ZMod p)) ^ 2)) * hx
  have hpos : 0 < a ^ 2 + b ^ 2 := by
    by_contra hc
    have ha0 : a = 0 := by nlinarith [sq_nonneg a, sq_nonneg b]
    have hb0 : b = 0 := by nlinarith [sq_nonneg a, sq_nonneg b]
    apply hne
    have e1 : u1 = u2 := Fin.ext (by omega)
    have e2 : v1 = v2 := Fin.ext (by omega)
    rw [e1, e2]
  have hmZ : (m : ℤ) * m < p := by
    have := lt_of_le_of_ne hm1 hmp
    exact_mod_cast this
  have hsa : a ^ 2 ≤ (m : ℤ) * m := by
    have h1 : a ≤ m := by omega
    have h2 : -(m : ℤ) ≤ a := by omega
    nlinarith
  have hsb : b ^ 2 ≤ (m : ℤ) * m := by
    have h1 : b ≤ m := by omega
    have h2 : -(m : ℤ) ≤ b := by omega
    nlinarith
  obtain ⟨k, hk⟩ := hdiv
  have hpZ : (0 : ℤ) < p := by exact_mod_cast hp.pos
  have hk1 : k = 1 := by
    have : 0 < k := by
      by_contra hc
      nlinarith
    have : k < 2 := by
      by_contra hc
      nlinarith
    omega
  subst hk1
  refine ⟨a.natAbs, b.natAbs, ?_⟩
  have : ((a.natAbs ^ 2 + b.natAbs ^ 2 : ℕ) : ℤ) = p := by
    push_cast
    rw [sq_abs, sq_abs]
    linarith
  exact_mod_cast this

import Mathlib.Data.Real.Basic
import Mathlib.Algebra.BigOperators.Fin

lemma amgm_bern (c d : ℝ) (hc : 0 ≤ c) (hcd : 0 ≤ c + d) :
    ∀ m : ℕ, c ^ m * (c + m * d) ≤ c * (c + d) ^ m := by
  intro m
  induction m with
  | zero => simp
  | succ m ih =>
    have h1 : c ^ m * (c + m * d) * (c + d) ≤ c * (c + d) ^ m * (c + d) :=
      mul_le_mul_of_nonneg_right ih hcd
    have h2 : 0 ≤ c ^ m * ((m : ℝ) * (d * d)) :=
      mul_nonneg (pow_nonneg hc m) (mul_nonneg (Nat.cast_nonneg m) (mul_self_nonneg d))
    have e1 : c ^ m * (c + m * d) * (c + d)
        = c ^ (m + 1) * (c + ((m + 1 : ℕ) : ℝ) * d) + c ^ m * ((m : ℝ) * (d * d)) := by
      push_cast; grind
    have e2 : c * (c + d) ^ m * (c + d) = c * (c + d) ^ (m + 1) := by grind
    grind

lemma amgm_step (A x : ℝ) (hA : 0 ≤ A) (hx : 0 ≤ x) (n : ℕ) :
    A ^ n * x ≤ ((n * A + x) / (n + 1)) ^ (n + 1) := by
  have hn : (0 : ℝ) < n + 1 := by
    have := Nat.cast_nonneg (α := ℝ) n
    grind
  have hB : 0 ≤ (n * A + x) / (n + 1) :=
    div_nonneg (add_nonneg (mul_nonneg (Nat.cast_nonneg n) hA) hx) hn.le
  have hmul : ((n : ℝ) + 1) * ((n * A + x) / (n + 1)) = n * A + x := by
    rw [mul_div_assoc']
    exact mul_div_cancel_left₀ _ hn.ne'
  rcases hA.lt_or_eq with hA' | hA'
  · have h := amgm_bern A ((n * A + x) / (n + 1) - A) hA (by grind) (n + 1)
    have e : A + ((n + 1 : ℕ) : ℝ) * ((n * A + x) / (n + 1) - A) = x := by
      push_cast; grind
    rw [e, show A + ((n * A + x) / (n + 1) - A) = (n * A + x) / (n + 1) by grind] at h
    have : A * (A ^ n * x) ≤ A * ((n * A + x) / (n + 1)) ^ (n + 1) := by
      calc A * (A ^ n * x) = A ^ (n + 1) * x := by grind
        _ ≤ _ := h
    exact le_of_mul_le_mul_left this hA'
  · subst hA'
    rcases n with _ | n
    · simp
    · simp only [ne_eq, Nat.add_one_ne_zero, not_false_eq_true, zero_pow, zero_mul]
      exact pow_nonneg hB _

lemma amgm_sum_nonneg : ∀ (n : ℕ) (x : Fin n → ℝ), (∀ i, 0 ≤ x i) → 0 ≤ ∑ i, x i := by
  intro n
  induction n with
  | zero => intro x _; simp
  | succ n ih =>
    intro x hx
    rw [Fin.sum_univ_castSucc]
    exact add_nonneg (ih _ (fun i => hx _)) (hx _)

theorem Lemma.am_gm : ∀ (n : ℕ) (x : Fin n → ℝ), (∀ i, 0 ≤ x i) → ∏ i, x i ≤ ((∑ i, x i) / n) ^ n := by
  intro n
  induction n with
  | zero => intro x _; simp
  | succ n ih =>
    intro x hx
    rw [Fin.prod_univ_castSucc, Fin.sum_univ_castSucc]
    have hS0 : 0 ≤ ∑ i : Fin n, x i.castSucc := amgm_sum_nonneg n _ (fun i => hx _)
    have hih := ih (fun i => x i.castSucc) (fun i => hx _)
    have hS00 : n = 0 → ∑ i : Fin n, x i.castSucc = 0 := by rintro rfl; simp
    generalize ∑ i : Fin n, x i.castSucc = S at hS0 hih hS00 ⊢
    have hSA : S = n * (S / n) := by
      rcases Nat.eq_zero_or_pos n with h | h
      · simp [hS00 h, h]
      · have : (n : ℝ) ≠ 0 := by exact_mod_cast h.ne'
        rw [mul_div_assoc']
        exact (mul_div_cancel_left₀ _ this).symm
    have hA : 0 ≤ S / n := div_nonneg hS0 (Nat.cast_nonneg n)
    have key := amgm_step (S / n) (x (Fin.last n)) hA (hx _) n
    rw [← hSA] at key
    push_cast
    calc (∏ i : Fin n, x i.castSucc) * x (Fin.last n)
        ≤ (S / n) ^ n * x (Fin.last n) := mul_le_mul_of_nonneg_right hih (hx _)
      _ ≤ _ := key